Monostable Circuit for Signal Monitoring

The circuit

The circuit shown next belongs to the family of monostable flip-flops. Depending on the ratio, c2/c1, and the number of pulses at the input, capacitor c2 will be charged up until the threshold level of inverter x1 has been reached. Regenerative feedback occurs which forces monoflop into its unstable state. When the input pulses disappear c2 will be discharged through r1 and the gates will finally return to the stable state. This type of circuit is used for monitoring tasks.

The input file

*** monostable circuit for signal monitoring ***

.control
tran 10ms 5s 0 10ms
plot v(1)+30 v(3) v(5)-20 xlabel t[s] ylabel 'v(1) v(3) v(5) [V]'
  + title 'TRAN analysis'
.endc

v1 6 0 dc 0 sin 0 10V 10Hz 0.3s
v2 6 1 dc 0 sin 0 10V 10Hz 2s

r1 3 0 2.2meg

c1 1 2 0.1uF
c2 3 5 2.2uF

d1 0 2 diode
d2 2 3 diode

x1 3 4 inv
x2 4 5 inv

.model diode d

.subckt inv 1 2
v1 3 0 dc 15V

d1 1 3 diode
d2 0 1 diode

m1 2 1 3 3 p4007 w=120um l=6um
m2 2 1 0 0 n4007 w=120um l=6um

.model diode d cjo=10pF

.model p4007 pmos
.model n4007 nmos
.ends

.end

The results