Monostable Multivibrators
The mostable, or one shot multivibrator, has only one stable
state. It is a hybrib between the astable and bistable multivibrators.
When triggered, the monostable flips to its unstable state where
it stays for a predetermined amount of time before flopping back
to its original stable state. This makes the monostable useful for
standardizing polses of arbitrary width or generating delayed pulses.
The circuit 1
The input file 1
monostable multivibrator 1
.control
tran 25ms 5s
plot v(1)+40 v(2)+20 v(3) v(5)-20 v(6)-40 xlabel t[s] ylabel voltages[V]
+ title 'TRAN analysis'
.endc
v1 1 0 dc 0 pulse 0 15V 1s 0 0 50ms 100s
r1 5 0 2.2meg
r2 2 6 100k
r3 1 7 10k
c1 2 7 1uF
c2 3 5 1uF
x3 2 3 invertor
x4 5 6 invertor
.subckt invertor 1 2
v1 4 0 dc 15V
c1 1 0 10P
d1 1 4 noname3
d2 0 1 noname3
m1 2 1 4 4 noname1
m2 2 1 0 0 noname2
.model noname3 d
.model noname1 pmos
.model noname2 nmos
.ends
.end
The results 1
The circuit 2
The input file 2
monostable multivibrator 2
.control
tran 25ms 5s
plot v(1)+40 v(2)+20 v(3) v(4)-20 xlabel t[s] ylabel voltages[V]
+ title 'TRAN analysis'
.endc
v1 1 0 dc 0 pulse 0 15V 1s 0 0 50ms 2s
r1 4 2 1meg
r2 4 6 100k
c1 6 3 1uF
d1 4 2 noname
d2 0 4 noname
x1 1 2 3 nor
x2 3 4 2 nor
.model noname d
.subckt nor 1 2 3
v1 5 0 dc 15V
c1 1 0 10pF
c2 2 0 10pF
m1 4 1 5 5 noname1
m2 3 2 4 4 noname1
m3 3 2 0 0 noname2
m4 3 1 0 0 noname2
.model noname1 pmos
.model noname2 nmos
.ends
.end
The results 2
|