Sound Pressure Response Of A Loudspeaker

The circuit

To complete this chapter, it will be shown that mechanical systems can be simulated with Spice. For this purpose, the sound pressure response of a loudspeaker will be investigated. In order to accomplish this, mechanical dimensions have to be converted into electrical dimensions which can then be represented in the form of electrical equivalent circuits. Mechanical damping forces find their analogy with ohmic resistances, mechanical masses with electrical capacitances, and elastic forces with inductances. Mechanical driving forces arising from current carrying voice coils can be imaged as electrical currents due to the force equation F = B * L * i. And the velocity, v, of a voice coil moving with the permanent field of a loudspeaker corresponds to the induced voltage E = B * L * v.

In the following example, the sound pressure response of a loudspeaker will be evaluated. As indicated in the bass boost preamplifier example, the roll-off of sound pressure at low frequencies may be equalised by electronic means or by the appropriate acoustic enclosures. Here, the enclosure alternative will be explored.

Loudspeakers need baffles, which prevent neutralisation of the sound pressure around opposite moving halves of a diaphragm, thus avoiding an acoustic short circuit. When using pressure tight closed boxes, instead of infinite baffles, the rearward radiation is absorbed by a damped cavity and no neutralisation effects occur down to the lowest frequency of interest. The air volume of an enclosure causes an elastic force, which adds to that of the speaker suspension thus, shifting the resonant frequency up to a higher value. A disadvantage is that speaker efficiency below the resonant frequency decreases considerably. It is desirable to shift the phase of the rearward radiation so that it can be added to the front radiation in proper phase. This can be realised by a vent, the cross section of which should be comparable to that of the speaker cone. In this vent, well defined air mass is excited by the rearward radiation. The air load may be replaced with the mass of a passive diaphragm.

As the simulation shows, the low cutoff frequency of the sound pressure may be lowered by one octave. Below this, the roll-off is stronger than that caused by a pressure tight closed box. For a given amplitude, x_a, of the diaphragm, the driving force F = B * L * i of the voice coil has to accelerate the mass, M_a, of the cone and air load to overcome the damping, D_a, of the radiation resistance, or stiffness, S_a, of the speaker suspension and S_b of the enclosure volume. The same is true for the amplitude, x_b, of the air mass, M_b, in the vent stimulated by the enclosure volume. These relations may be expressed by the motion equations:

As a further step, the system of differential equations will be transformed from the time domain into the frequency domain by the Laplacian operation. With E₀ = B * L * dx_a/dt and E₁ = B * L * dx_b/dt, the following equations are obtained:

As an image of the driving force, F, the voice coil current, i, is dis-played as a sum of fractional currents flowing through the respective impedances. With the help of the resulting nodes and meshes, an electrical equivalent circuit of a speaker may be drawn easily.

The input file

sound pressure response of a loudspeaker

.control
ac dec 65 10Hz 10kHz
alter c2 capacitance = 100uF
ac dec 65 10Hz 10kHz
alter c2 capacitance = 299uF
ac dec 65 10Hz 10kHz
alter c2 capacitance = 700uF
ac dec 65 10Hz 10kHz
plot db(ac1.i(vz)) db(ac2.i(vz)) db(ac3.i(vz)) db(ac4.i(vz)) xlabel f[Hz]
  + ylabel i(vz)[dB] title 'AC analyses'
.endc

v1 0 1 dc 0 ac 1
vx 5 10 dc 0
vy 11 10 dc 0
vz 10 0 dc 0

r1 1 2 7
r2 3 0 53.05
r3 4 5 3.83
r4 7 8 3.83
r5 9 11 1m

c1 3 0 151uF
c2 6 0 1
c3 3 4 84.62uF
c4 6 7 84.62uF

l1 2 3 0.25mH
l2 3 0 20.4mH
l3 3 6 48.5mH
l4 8 0 1H
l5 0 9 1H

k45 l4 l5 0.999999

.end

The results