updated 2000.12.01
Author Janez Puhan
Bass Boost Preamplifier
The circuit
It is known that the radiation resistances of loudspeaker diaphragms have a roll-off below frequencies whose wavelengths approach the diameter of the speaker cone. The typical transition frequency is about 300Hz. Below this frequency, the sound pressure decreases at 6dB/octave. Fortunately, the speaker cone suspension system resonates with the mass causing the roll-off to be smoothed to a certain extent. Below this mechanical response, however, the slope steps down at 12dB/octave. Equalisation of the sound pressure down to the lower limit of audibility requires special enclosures or electronic measures. In this section, bass boost is achieved by a notch filter within the negative feedback path of a preamplifier.
The input file
bass boost preamplifier
.control
set abstol = 1e-10
ac dec 50 10Hz 10kHz
* phase should be continuous
set units = degress
let phase = vp(5) + 360 * (vp(5) lt 0)
plot vdb(5) phase/10 xlabel f[Hz] ylabel output[dB][degree] title 'AC analysis'
unlet phase
.endc
v1 1 0 dc 0 ac 1V
v2 7 0 dc -15V
v3 8 0 dc 15V
r1 4 0 1.5k
r2 3 5 20k
r3 1 2 10k
r4 2 3 100k
c1 3 4 1uF
c2 4 5 1uF
x1 2 0 5 8 7 op07
.subckt op07 2 3 6 7 4
vofst 300 3 10uV
iofst 2 3 300pA
iee 4 14 62nA
iro 20 19 170uA
rcm 13 4 10meg
rc1 11 10 1k
rc2 11 12 1k
rp 7 4 10k
r2 15 0 100k
ro2 16 0 1k
rr0 16 21 0.1meg
rl1 21 6 1k
ccm 13 4 2.5pF
chf 10 12 91.667pF
c2 15 16 30pF
l1 21 6 50uH
ga 0 15 12 10 0.9mS
gcm 0 15 13 0 6.3nS
gb 16 0 15 0 22.5S
bn 0 18 v = -v(4) - 2.3
bp 17 0 v = v(7) - 1.8
d1 7 11 d741
d2 15 0 d741 off
d3 0 15 d741 off
d4 16 17 d741p off
d5 18 16 d741p off
d6 19 16 d741
d7 16 20 d741
q3 13 14 4 qn741
q4 7 19 21 qno
q5 4 20 21 qpo
qni1 10 2 13 qni1
qni2 12 300 13 qni1
.model d741 d (cjo=3pF)
.model d741p d (rs=1m)
.model qn741 npn
.model qno npn (bf=150 cjc=3p is=1e-14)
.model qpo pnp (bf=150 cjc=3p is=1e-14)
.model qni1 npn (nf=843.33m bf=8.8571k is=8e-16 cje=3pF)
.ends
.end
The results
