Frequency Discriminator

The circuit

With amplitude modulation (AM), the information is contained within the instantaneous amplitudes in the high frequency carrier. With frequency modulation (FM), the information is hidden in the instantaneous deviation of frequency, while the amplitude remains constant. Circuits as described in previous case are not suited for the demodulation of frequency modulated carriers. A discriminator which converts frequency deviations into amplitude deviations has to be utilised. This could be a Bradley oscillator, a Foster-Seeley discriminator, or a ratio detector to name but a few. In the following example, an arrangement of two resonant circuits is shown. Depending on the coupling coefficients, k13 and k14, two resonant curves will occur side by side. Summation of these waveforms results in one double hump resonant curve. Subtraction, however, leads to a S-like discriminator characteristic where a more or less linear relationship between frequency and amplitude may be expected.

The input file

frequency discriminator

.control
ac lin 100 10.2megHz 11.2megHz
plot vm(6) vm(5) xlabel f[Hz] ylabel 'magnitude of the difference/addition [V]'
  + title 'AC analysis'
plot vm(4)+vm(3) vm(4)-vm(3) xlabel f[Hz]
  + ylabel 'difference/addition of the magnitudes [V]' title 'AC analysis'
.endc

i1 1 0 dc 0 ac 1mA

c1 1 0 27pF
c2 3 4 33pF

l1 1 0 8.194uH
l2 2 0 1.277uH
l3 3 2 1.676uH
l4 2 4 1.676uH

k12 l1 l2 0.999
k13 l1 l3 0.025
k14 l1 l4 0.025
k34 l3 l4 0.999

r1 3 0 10k
r2 4 0 10k

x2 3 4 5 sum1
x3 3 4 6 sum2

.subckt sum1 1 2 3
rin1 1 0 1e12
rin2 2 0 1e12
rout 3 0 1e12

e1 3 0 2 1 1
.ends

.subckt sum2 1 2 3
rin1 1 0 1e12
rin2 2 0 1e12
rout 3 0 1e12

e1 3 4 2 0 1
e2 4 0 1 0 1
.ends

.end

The results