Transformerless DC Voltage Converter
The circuit
Generation of high DC voltages leads to corona and isolation effects in wire
windings when transformers are used. A transformerless voltage multiplier
can be more suitable for conversion of low DC voltages to higher ones. It
can be accomplished with a network of diodes and capacitors which rectifies
a chopped DC input voltage and additively charges capacitors to the desired
high voltage level.
In the following example, the input voltages, v1 and v2,
are chopped by an astable multivibrator composed mainly of an operational
amplifier, e1, and two MOSFETs, m1 and m2. The multiplier
capacitors are charged up to the peak to peak amplitude of the square wave
voltage at node (1). The resulting DC output voltage, therefore, depends on
the number of cascaded capacitors.
The input file
transformerless dc voltage converter
.control
tran 0.25ms 100ms
plot v(1) v(2) v(13) v(14) xlabel t[s] ylabel 'v(1) v(2) output [V]'
+ title 'TRAN analysis'
.endc
v1 5 0 dc 0 pwl 0 0 1ms 15V
v3 6 0 dc 0 pwl 0 0 1ms -15V
r1 2 1 10k
r2 3 1 10k
r3 0 3 1k
c1 2 0 1uF
c2 3 0 0.1uF
c3 7 1 1uF
c4 1 8 1uF
c5 5 9 1uF
c6 6 10 1uF
c7 7 11 1uF
c8 8 12 1uF
c9 9 13 1uF
c10 10 14 1uF
d1 5 7 dio
d2 8 6 dio
d4 7 9 dio
d5 10 8 dio
d6 9 11 dio
d7 12 10 dio
d8 11 13 dio
d9 14 12 dio
m2 1 4 6 6 noname2 w=1.2mm l=6um
m9 1 4 5 5 noname1 w=1.2mm l=6um
x1 2 3 4 5 6 ua741
.model dio d cjo=3pF
.model noname1 pmos rd=1 cbd=1uF
.model noname2 nmos rd=1 cbd=1uF
.subckt ua741 11 7 5 23 2
r1 13 2 1k
r2 12 2 50k
r3 14 2 1k
r4 15 2 5k
r5 21 2 50k
r6 22 2 100
r7 17 16 39k
r8 18 19 4.5k
r9 19 20 7.5k
r10 24 5 50
r11 5 8 25
c1 18 10 30pF
q1 26 11 25 qnl
q2 26 7 1 qnl
q3 9 6 25 qpl
q4 10 6 1 qpl
q5 9 12 13 qnl
q6 10 12 14 qnl
q7 23 9 12 qnl
q8 26 26 23 qpl
q9 6 26 23 qpl
q10 6 16 15 qnl
q11 16 16 2 qnl
q12 17 17 23 qpl
q13 18 17 23 qpl
q14 18 19 20 qnl
q15 20 10 21 qnl
q16 20 21 22 qnl
q17 10 4 2 qnl
q18 18 24 5 qnl
q19 4 8 5 qpl
q20 4 4 2 qnl
q21 23 18 24 qnl
q22 2 20 18 qpl
.model qnl npn bf=150 rb=100 va=200 ccs=2pF cje=3pF cjc=2pF tf=0.3ns tr=6ns
.model qpl pnp bf=80 rb=20 va=200 cje=6pF cjc=4pF tf=1ns tr=20ns
.ends
.end
The results
|