updated 2000.03.30
Author Janez Puhan
Power Inverter with Trapezoidal Waveform
The circuit
As the average system clock speeds have continuously increased into higher realms, electromagnetic compatibility of electronic equipment has become an increasingly significant factor in circuit design. Switching regulated power supplies working with sharply rising square waves can be problematic, because these generate a broad spectrum of frequencies reaching up to the microwave region. In order to limit the expense on screening and filtering, inverters have been developed that operate with trapezoidal waveforms. For this purpose, a capacitor c2 may be added to the inductance l1 on the transformer as shown in the following circuit. The resulting resonant network is tuned to a fundamental frequency of operation with higher order harmonics that are considerably attenuated. The waveform approaches that of a sine wave, if we disregard the fact that the negative part is clipped off and limited to the common ground potential. The clip-off period depends on the conducting angles of q1 and the free wheeling diode, d3, which is needed for energy recuperation. The following graphs show the behaviour of the inverter with no load (r5 = 1GW) and with full load (r5 = 1W).
The input file
power inverter with trapezoidal waveform
.control
tran 4us 10ms 8ms 5us uic
plot v(1)+22 v(2)/30 (v(4)+6)*20 i(v0)-15 xlabel t[s]
+ ylabel 'v(1) v(2) v(4)[V] i(v0)[A]' title 'No Load'
alter r5 resistance = 1
tran 4us 10ms 8ms 5us uic
plot v(1)+22 v(2)/30 (v(4)+5)*10 i(v0)-15 xlabel t[s]
+ ylabel 'v(1) v(2) v(4)[V] i(v0)[A]' title 'Full Load'
.endc
v0 3 0 dc 110V
r1 6 5 15
r2 4 0 100
r3 1 3 15k
r4 5 4 150
r5 7 0 1g
c1 4 0 100uF
c2 2 3 1uF
l1 3 2 2mH
l2 1 6 15uH
l3 7 0 20uH
k12 l1 l2 0.995
k13 l1 l3 0.995
k23 l2 l3 0.995
d1 4 5 diode
d2 4 1 diode
d3 0 2 diode
q1 2 1 0 bjtn
.model diode d
.model bjtn npn (ikf=6)
.end
The results
