Controlled Blocking Oscillator

The circuit

Mobile electronic equipment such as laptop computers and telecommunications equipment has to be powered from batteries. To achieve higher dc voltages, a series connection of several single cells is utilised. Due to the spread of charge capacities, the lifetime of a battery depends on the condition of the weakest cells. In applications where reliable operation is of primary interest only one single cell is permitted. Higher dc voltages then have to be stepped up by dc converters. A circuit used for this purpose is shown next in the form of a blocking oscillator. A low dc input voltage is chopped by a switching transistor, q1, the transformed and rectified again. The frequency of the regenerative switching action is determined by positive feedback, via l2, and ranges between 20 - 200kHz. To be independent of variations in battery voltage and load resistance, the dc voltage is stabilised by a "bang bang" control circuit. The reference element is a zener diode, d3. When conducting, q1 will be turned off until the dc output voltage has dropped down to nominal value.

The input file

controlled blocking oscillator

.control
tran 0.2us 100us uic
plot v(1)-5 v(2) (v(7)-15)*10+25 i(v0)-15 xlimit 10u 100u xlabel t[s]
  + ylabel 'v(1) v(2) output [V] / i(v0)[A]' title 'TRAN analysis'
.endc

v0 3 0 dc 3.5V

r1 1 5 33
r2 3 4 1k
r3 7 0 150
r4 8 7 1k
r5 9 0 1k

c1 7 0 22uF ic=15V

l1 2 3 10uH
l2 4 5 10uH
l3 6 0 250uH

k12 l1 l2 0.995
k13 l1 l3 0.995
k23 l2 l3 0.995

d1 0 4 dn4001
d2 6 7 dn5819
d3 9 8 zener

q1 2 1 0 bfx62
q2 1 9 0 bcy59c

.model dn4001 d (is=1.4n rs=0.04 n=1.7 tt=5u cjo=55p vj=0.2 mj=0.38 bv=75)
.model dn5819 d (is=2u rs=0.03 n=1 tt=100p cjo=250p vj=0.2 mj=0.18)
.model zener d (rs=15 bv=14V)
.model bfx62 npn (is=15n bf=180 nf=1.67 vaf=100 ikf=2.0 br=4 rc=.2 cje=500p
  + tf=1.8n cjc=70p tr=25n)
.model bcy59c npn (is=36f bf=300 nf=1 vaf=35 ikf=40m br=10 rc=.9 cje=13p
  + tf=.5n cjc=6p tr=100n)

.end

The results