Windingless Capacitor 1

Not only inductors, but also capacitors, can be realised with integrated circuits. This may be advantageous to some applications due to the savings in weight and space. In contrast to inductors, capacitive current has a phase lead of 90 degrees with respect to voltage. Like inductors, deviations from the ideal phase shift are a measure of the losses dissipated in ohmic resistors in series with the capacitor.

The circuit

The input file (windingless_capacitor_1.cir)

electronic capacitor I
* C series = c1 r2 / r1
* R series = r1

.control
   set units = degrees
   ac dec 40 0.01Hz 1kHz
   plot db(i(v1)) ph(i(v1)) ydelta 10 xlabel frequency[hertz]
   + ylabel current_magnitude[decibell]_and_phase[degree] 
   + title ac_analysis
   plot mag(i(v1)) real(i(v1)) imag(i(v1)) xlabel frequency[hertz]
   + ylabel current[amper] title ac_analysis
.endc

v1 0 1 dc 0 ac 1

r1 4 1 1k
r2 2 3 100k

c1 3 0 10nF

e1 2 0 1 2 1meg
e2 4 0 3 4 1meg

.end

The results

Windingless Capacitor 2

A less expensive circuit is shown next. As with all discrete inductors and capacitors, the maximum voltage and current ratings have to be taken into account with synthetic realisations. Voltage breakdown within real capacitors are comparable to the maximum voltage swing of an electronic capacitor and saturation of the flux density within normal inductors corresponds with the maximum available current of the electronic counterpart.

The circuit

The input file (windingless_capacitor_2.cir)

electronic capacitor II

* C series = c1 (1 + r2 / r1)
* R series = r1 r2 / (r1 + r2)

.control
set units = degrees
ac dec 40 0.01Hz 1kHz
plot db(i(v1)) ph(i(v1)) xlabel f[Hz]
  + ylabel 'current magnitude [dB] / phase[degree]' title 'AC analysis'
plot mag(i(v1)) real(i(v1)) imag(i(v1)) xlabel f[Hz] ylabel current[A]
  + title 'AC analysis'
.endc

v1 0 1 dc 0 ac 1

r1 1 2 1k
r2 1 3 100k

c1 3 0 10nF

e1 2 0 3 2 1meg

.end

The results