Logarithmic DC Amplifier

The circuit

In initial simulation stages, it is preferable to use idealized components in order to get the simulation going. Higher order nonlinearities and more realistic models can then be added as the simulation is refined. Also, by partitioning a complete system into several subsystems, localization of possible errors or problem areas can be made much easier. These factors lead us to the creation of an ideal op-amp. The idealized operational amplifier is a voltage controlled voltage source with infinite gain, infinite bandwidth, and an infinite input and output voltage swing. In the following example, a logarithmic transfer function is approximated by six piece-wise linear sections and an ideal op-amp.

The input file (logarithmic_dc_amplifier.cir)

logarithmic dc amplifier

* v(3) = 6 + 4 log(v(1))

* y = 12.75 x ********* 0 < x < 0.3125
* y = 4 x + 2.7 ******* 0.3125 < x < 0.625
* y = 2 x + 3.91 ****** 0.625 < x < 1.25
* y = x + 5.16 ******** 1.25 < x < 2.5
* y = 0.5 x + 6.41 **** 2.5 < x < 5
* y = 0.219 x + 7.81 ** 5 < x < 10

* v(1) / r1 = v(3) / r7 + (v(3) - vd5) / r6 + (v(3) - vd4) / r5 +
************* (v(3) - vd3) / r4 + (v(3) - vd2) / r3 + (v(3) - vd1) / r2

.control
dc v1 0 10V 0.05V
plot v(3) xlabel v1[V] ylabel output[V] title 'DC analysis'
.endc

v1 0 1 dc 0

r1 1 2 10k
r2 4 3 3.865k
r3 5 3 10k
r4 6 3 20.56k
r5 7 3 39.35k
r6 8 3 55.26k
r7 3 2 127.5k

eopamp 3 0 0 2 1meg

d1 2 4 zener1
d2 2 5 zener2
d3 2 6 zener3
d4 2 7 zener4
d5 2 8 zener5

.model zener1 d bv=8.91V
.model zener2 d bv=7.66V
.model zener3 d bv=6.41V
.model zener4 d bv=5.16V
.model zener5 d bv=3.98V

.end

The results