CMOS Operational Amplifier

The circuit

Operational amplifiers are basically differential amplifiers. They have an inverting and non-inverting input. Only voltage differences between these two inputs are sensed and amplified. Common mode input voltages with respect to ground should be suppressed to a high degree. This effect can be achieved by supplying the differential input MOSFETs with a current source, m5. The circuit shown next is similar to the well known MC14573 op-amp. With the exception of a small capacitor, c1, which provides frequency compensation, the amplifier is built up with complementary MOSFETs. The transfer characteristic has been established by proper selection of the channel width, w =, and channel length, l =. The dc analysis shows that the shift of the differential transfer characteristic due to common mode voltages is held within narrow limits.

The input file (cmos_operational_amplifier.cir)

cmos operational amplifier

.control
dc v1 -1mV 1mV 0.04mV v2 2V 8V 3V
let output_at_2volt = (v(1)[0, 50])
let output_at_5volt = (v(1)[51, 101])
let output_at_8volt = (v(1)[102, 152])
plot output_at_2volt output_at_5volt output_at_8volt xlabel 'differential input [V]'
  + ylabel output[V] title 'DC analysis'
destroy
.endc

v0 7 0 dc 10V
v1 2 3 dc 0
v2 2 0 dc 0
v3 8 7 dc -2.2V

m1 5 2 6 7 pkanal l=1.3u w=15u
m2 4 3 6 7 pkanal l=1.3u w=15u
m3 5 5 0 0 nkanal l=2.5u w=8u
m4 4 5 0 0 nkanal l=2.5u w=8u
m5 6 8 7 7 pkanal l=1.3u w=2.7u
m6 1 8 7 7 pkanal l=1.3u w=13u
m7 1 4 0 0 nkanal l=2.5u w=74u

.model nkanal nmos (vto=1.2 kp=35u lambda=.02 tox=40n)
.model pkanal pmos (vto=-1.2 kp=12u lambda=.02 tox=40n)

.end

The results